modules/network.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68

{ config, lib, ... }:
let
  cfg = config.depot.net;
  inherit (lib)
    mkOption
    types
    ;

  quad9 = [
    "9.9.9.9#dns.quad9.net"
    "149.112.112.112#dns.quad9.net"
    "2620:fe::fe#dns.quad9.net"
    "2620:fe::9#dns.quad9.net"
  ];

  cloudflare = [
    "1.1.1.1#one.one.one.one"
    "1.0.0.1#one.one.one.one"
    "2606:4700:4700::1111#one.one.one.one"
    "2606:4700:4700::1001#one.one.one.one"
  ];

in
{
  imports = [
    ./sshd.nix
  ];

  options.depot.net = {
    v6Token = mkOption {
      type = types.str;
      default = "eui64";
      description = "Token for global v6 address, defaults to eui64";
    };
  };

  config = {
    # networkd handles this
    networking.useDHCP = false;

    systemd.network.enable = true;
    systemd.network.networks = {
      "10-base" = {
        matchConfig = {
          Name = "*";
          Type = "ether";
        };

        ipv6AcceptRAConfig.Token = cfg.v6Token;

        networkConfig = {
          DHCP = "ipv4";
          UseDomains = true;

          # Enable MDNS resolve/publish over this network
          MulticastDNS = true;
        };
      };
    };

    networking.firewall.allowedUDPPorts = [ 5353 ];

    services.resolved = {
      enable = true;
      settings.Resolve.FallBackDNS = quad9 ++ cloudflare;
    };
  };
}